Add a test sim with an MLP bed in it.

No animations yet, wont need them until later, maybe wont need them until this is ready for in world testing.

2 files changed, 825 insertions, 0 deletions

diff --git a/LuaSL/Test sim/objects/onefang's test bed/~menu b/LuaSL/Test sim/objects/onefang's test bed/~menu
new file mode 100644
index 0000000..ea19396
--- /dev/null
+++ b/LuaSL/Test sim/objects/onefang's test bed/~menu
@@ -0,0 +1,529 @@
+// MLPV2 Version 2.3, by Learjeff Innis, based on
+// MLP MULTI-LOVE-POSE V1.2 - Copyright (c) 2006, by Miffy Fluffy (BSD License)
+// 15-color balls by Lizz Silverstar
+// OpenSim port by Jez Ember
+// Meta 7 fixes by onefang Rejected
+
+// 2.3: sequences
+//      6 avs
+//      Adjusting state
+
+integer MAX_BALLS   = 6;
+
+string  Version      = "MLPV2.5";
+
+integer b;
+integer b0;
+integer ballusers;
+list    BallColors;
+integer ch;
+integer chat = 1;
+integer group;
+integer i;
+integer menu;
+integer menuusers;
+integer redo = 1;
+integer swap;
+integer visible;
+integer BallCount;
+integer SaneMenuOrder;
+integer ReloadOnRez;
+
+integer Adjusting;
+string  LastPose;
+
+integer BallsNeeded;
+
+float alpha;
+string cmd;
+string pose;
+string Posemsg;     // for 'AGAIN'
+key owner;
+key user;
+key user0;
+list buttons;
+list buttonindex;
+list commands;
+list menus;
+list balls;
+list users;
+
+list SoundNames;
+list Sounds;
+list LMButtons;
+list LMParms;
+list MenuStack = [0];     // indices to previous menus, for "BACK" command
+
+integer MenuPage;       // which page of current menu we're on, 0 for first
+
+// Replacement for llListFindList which is currently broken in OSLSL
+integer myListFind(list a, string b) {
+    integer x;
+    integer l=llGetListLength(a);
+
+    for(x=0; x<l; x++) {
+        if(llList2String(a,x) == b) {
+            return x;
+        }
+    }
+    
+    return -1;
+}
+
+stop() {
+    sendStand();     //msg to pos/pose
+    llMessageLinked(LINK_THIS, 1, "STOP", (key)"");
+    llSleep(0.2);
+    killBalls();
+    swap = 0;
+    Adjusting = FALSE;
+}
+
+
+check_poses() {
+    llOwnerSay("Checking configs");
+    llMessageLinked(LINK_THIS,0,"POSEB", (key)"CHECK1");                        //msg to memory
+    integer ix;
+    string name;
+    for (ix = 0; ix < llGetListLength(buttons); ++ix) {
+        name = llList2String(buttons, ix);
+        if (((integer)llList2String(commands, ix)) != 0) {
+            llMessageLinked(LINK_THIS,0,"POSEB", (key)name);                    //msg to memory
+        }
+    }
+    llMessageLinked(LINK_THIS,0,"POSEB", (key)"CHECK2");                        //msg to memory
+}
+
+// Return a channel number that's based on the prim's key -- unique per object
+integer channel() {
+    return (integer)("0x"+llGetSubString((string)llGetKey(),-4,-1));
+}
+
+
+// setup for a pose based on menu characteristics
+setup_pose() {
+    if (BallsNeeded) {                  // if submenu includes balls:
+        if (BallCount != BallsNeeded) {
+            rezBalls();       // if not enough balls present: create balls
+            llSleep(0.5);
+        }
+        integer ix;
+        for (ix = 0; ix < BallsNeeded; ++ix) {
+            llSay(ch + ix, llList2String(BallColors, ix)     // to ball: color, ballnum, adjusting
+                + "|" + (string) ix
+                + "|" + (string) Adjusting);
+        }
+        if (ballusers) setBalls("GROUP");           //if group access only
+    }
+}
+
+
+unauth(string button, string who) {
+        llDialog(user0, "\n" + button + " button allowed only for " + who, ["OK"], -1);
+}
+
+continMenu(string str) {
+    llDialog(user0, "\n"+str+llKey2Name(user)+" is using the menu, continue?", ["Yes","Cancel"], ch - 1);
+}
+
+mainMenu() {
+    MenuPage = 0;
+    menu = 0;
+    doMenu(FALSE);
+}
+
+//menu partly based on Menu Engine by Zonax Delorean (BSD License)
+//llDialog(user, menuname, buttons(from index to nextindex-1), channel)  
+doMenu(integer inhibit_showing) {
+    integer colors = llList2Integer(balls,menu);
+    integer ix;
+    integer mask = 0xf;
+    integer shift = 0;
+    BallsNeeded = 0;
+    BallColors = [];
+
+    for (ix = 0; ix < MAX_BALLS; ++ix) {
+        integer bc = (colors & mask) >> ix*4;
+        BallColors += (list)bc; 
+        if (bc) {
+            BallsNeeded += 1;
+        }
+        mask = mask << 4;
+    }
+    
+    if (inhibit_showing) {
+        return;
+    }
+
+    b0 = llList2Integer(buttonindex, menu);         //position of first button for this (sub)menu
+    b = llList2Integer(buttonindex, menu+1);        //position of first button for next (sub)menu
+
+    b0 += MenuPage * 12;
+    if (b - b0 > 12) {
+        b = b0 + 12;
+    }
+    
+    list buttons1;
+    buttons1 = llList2List(buttons, b0, b - 1);
+    if (SaneMenuOrder) {
+        buttons1 =
+              llList2List(buttons1, -3, -1)
+            + llList2List(buttons1, -6, -4)
+            + llList2List(buttons1, -9, -7)
+            + llList2List(buttons1, -12, -10);
+    }
+    llDialog(user, Version + "\n\n" + llList2String(menus,menu), buttons1, ch - 1);
+    llResetTime();
+}
+
+say(string str) {
+    if (menuusers) llWhisper(0,str);
+    else llOwnerSay(str);
+}
+
+killBalls() {
+    integer ix;
+    for (ix = 0; ix < MAX_BALLS; ++ix) {
+        llSay(ch + ix, "DIE");      //msg to balls
+    }
+    BallCount = 0;
+    llSetTimerEvent(0.0);
+}
+
+setBalls(string cmd) {
+    integer ix;
+    for (ix = 0; ix < BallCount; ++ix) {
+        llSay(ch + ix, cmd);      //msg to balls
+    }
+}
+
+
+rezBalls() {
+    integer current = BallCount;
+
+    if (BallsNeeded == BallCount) return;
+
+    if (BallCount == 0) {
+        killBalls();  // for reinitialization, if old balls are around
+    }
+
+    while (BallCount > BallsNeeded) {
+        --BallCount;
+        llSay(ch + BallCount, "DIE");
+    }
+    
+    while (BallCount < BallsNeeded) {
+        llRezObject("~ball",llGetPos(),ZERO_VECTOR,ZERO_ROTATION,ch+BallCount);
+        ++BallCount;
+    }
+    
+    // Only do this if there were no balls
+    if (! current) {
+        llMessageLinked(LINK_THIS,0,"REPOS",(key)"");  //msg to pos
+    }
+    
+    llSetTimerEvent(30.0);
+}
+
+
+
+sendStand() {
+    llMessageLinked(LINK_THIS,0,"POSE","0,"+(string)BallCount);        //msg to pos/pose
+    llMessageLinked(LINK_THIS,0,"POSEB", "stand");
+}
+
+touched(integer same_group) {
+    if (user0 == owner || (menuusers == 1 && same_group) || menuusers == 2) {   //0=owner 1=group 2=all
+        if (user0 != user) {
+            if (llGetTime() < 60.0 && user != (key)"") {
+                continMenu("");
+                return;
+            }
+            user = user0;
+            group = same_group;
+        }
+        mainMenu();
+    }
+}
+
+
+// return TRUE if caller should do menu
+integer handle_cmd(string button, integer sequenced) {
+    b = myListFind(buttons, button);                     //find position of cmd
+    string cmd = llList2String(commands,b);                         //get command
+
+    if (cmd == "TOMENU") {
+        integer newmenu = myListFind(menus, button);         //find submenu
+        if (newmenu == -1) return FALSE;
+        if (sequenced) {
+            integer oldmenu = menu;
+            menu = newmenu;
+            doMenu(TRUE);
+            setup_pose();
+            menu = oldmenu;
+            return FALSE;
+        }
+        i = llList2Integer(users, newmenu); 
+        if (user == owner || (i == 1 && group) || i == 2) {         //0=owner 1=group 2=all
+            MenuStack = (list)menu + MenuStack;
+            MenuPage = 0;
+            menu = newmenu;
+            doMenu(sequenced);
+            return FALSE;
+        }
+        if (i == 1) unauth(button, "group");
+        else unauth(button, "owner");
+        return FALSE;
+    } else if (cmd == "BACK") {
+        if (MenuPage) {
+            --MenuPage;                                           
+            doMenu(sequenced);
+            return FALSE;
+        }
+        menu = llList2Integer(MenuStack,0);
+        MenuStack = llList2List(MenuStack,1,-1);
+        doMenu(sequenced);
+        return FALSE;
+    } else if (cmd == "MORE") {
+        ++MenuPage;
+        doMenu(sequenced);
+        return FALSE;
+    } else if (cmd == "CHECK") {
+        check_poses();
+    } else if ((integer)cmd > 0) {                                  //POSE
+        if (Adjusting && button != pose) {
+            llMessageLinked(LINK_THIS,0,"SAVE",pose);               //msg to pos/pose
+            llSleep(5.);
+        }
+        setup_pose();
+        Posemsg = cmd + "," + (string) BallCount;
+        llMessageLinked(LINK_THIS,0,"POSE", Posemsg);               //msg to pose
+        llMessageLinked(LINK_THIS,0,"POSEB", (key)button);          //msg to memory
+        if (chat) say(button);
+        pose = button;
+    } else if (cmd == "SWAP") {
+        swap += 1;
+        llMessageLinked(LINK_THIS,0,"SWAP",(key)((string)swap));              //msg to pos/pose
+    } else if (cmd == "STAND") {
+        sendStand();     //msg to pos/pose
+        if (chat) say(button);
+        pose = "stand";
+    } else if (cmd == "STOP") {
+        if (chat) say(button);
+        stop();
+        return FALSE;
+    } else if (cmd == "ADJUST") {
+        Adjusting = ! Adjusting;
+        setBalls("ADJUST|" + (string)Adjusting);
+    } else if (cmd == "HIDE") {
+        setBalls("0");
+    } else if (cmd == "SHOW") {
+        setBalls("SHOW");
+    } else if (cmd == "DUMP") {
+        llMessageLinked(LINK_THIS,1,"DUMP",(key)"");
+    } else if (cmd == "INVISIBLE") {
+        visible = !visible;
+        llSetAlpha((float)visible*alpha, ALL_SIDES);
+    } else if (cmd == "REDO") {
+        redo = !redo;
+        if (redo) say(button+" ON"); else say(button+" OFF");
+    } else if (cmd == "CHAT") {
+        chat = !chat;
+        if (chat) say(button+" ON"); else say(button+" OFF");
+    } else if (cmd == "BALLUSERS") {
+        ballusers = !ballusers;
+        if (ballusers) {
+            llOwnerSay(button+" GROUP");
+            setBalls("GROUP");
+        } else {    
+            llOwnerSay(button+" ALL");
+            setBalls("ALL");
+        }
+    } else if (cmd == "MENUUSERS") {
+        if (user == owner) {
+            if (!menuusers) {
+                menuusers = 1;
+                llOwnerSay(button+" GROUP");
+            } else if (menuusers == 1) {
+                menuusers = 2;
+                llOwnerSay(button+" ALL");
+            } else if (menuusers == 2) {
+                menuusers = 0;
+                llOwnerSay(button+" OWNER");
+            }
+        } else unauth(button, "owner");
+    } else if (cmd == "RESET" || cmd == "RELOAD" || cmd == "RESTART") {
+        stop();
+        if (chat) say(button);
+        if (cmd == "RESET") {
+            llResetScript();
+        } else {
+            llResetOtherScript("~memory");
+            if (cmd == "RESTART") {
+                llResetScript();
+            }
+        }
+    } else if (cmd == "OFF") {
+        sendStand();     //msg to pos/pose
+        stop();
+        if (user == owner) {
+            llOwnerSay(button);
+            llResetOtherScript("~run");
+            llResetScript();
+        }
+        unauth(button, "owner");
+        return FALSE;
+    } else if (llGetSubString(cmd, 0, 0) == "Z" || (cmd == "SAVE")) {    //SAVE or Z-adjust
+        llSay(0,"Z");
+        llMessageLinked(LINK_THIS,0,cmd,pose);                           //msg to pos/pose
+        doMenu(sequenced);
+        return FALSE;
+    } else if (cmd == "LINKMSG") {
+        // menu button to send LM to a non-MLPV2 script
+        integer ix = myListFind(LMButtons, button);
+        if (ix != -1) {
+            list lmparms = llCSV2List(llList2String(LMParms, ix));
+            llMessageLinked(
+                llList2Integer(lmparms, 1),     // destination link#
+                llList2Integer(lmparms, 2),     // 'num' arg
+                llList2String(lmparms, 3),      // 'str' arg
+                user0);                         // key arg
+            if (llList2Integer(lmparms,0)) {    // inhibit remenu?
+                return FALSE;                         //   yes, bug out
+            }
+        }
+    } else if (cmd == "SOUND") {
+        integer ix = myListFind(SoundNames, button);
+        if (ix >= 0) {
+            llPlaySound(llList2String(Sounds, ix), 1.);
+        }
+    }
+    return TRUE;
+}
+
+default {
+    state_entry() {
+        ch = channel();
+        killBalls();
+        llSleep(2.0);       // give ~run a chance to shut us down
+        llResetOtherScript("~menucfg");
+        llResetOtherScript("~pos");
+        llResetOtherScript("~pose");
+        llResetOtherScript("~poser");
+        llResetOtherScript("~poser 1");
+        llResetOtherScript("~poser 2");
+        llResetOtherScript("~poser 3");
+        llResetOtherScript("~poser 4");
+        llResetOtherScript("~poser 5");
+        alpha = llGetAlpha(0);                                          //store object transparancy (alpha)
+        if (alpha < 0.1) alpha = 0.5; else visible = 1;                 //if invisible store a visible alpha
+    }
+
+    link_message(integer from, integer num, string str, key id) {
+        if (from != llGetLinkNumber()) { return; }
+        if (num >= 0) { return;}
+        
+        // LMs from ~memory, passing configuration
+        if (num == -1) {
+            buttons = llCSV2List(str);
+        } else if (num == -2) {
+            commands = llCSV2List(str);
+        } else if (num == -3) {
+            menus = llCSV2List(str);
+        } else if (num == -4) {
+            buttonindex = llCSV2List(str);
+        } else if (num == -5) {
+            balls = llCSV2List(str);
+        } else if (num == -6) {
+            users = llCSV2List(str);
+        } else if (num == -7) {
+            LMButtons = llCSV2List(str);
+        } else if (num == -8) {
+            LMParms = llParseStringKeepNulls(str, ["|"], []);
+        } else if (num == -9) {
+            SoundNames = llCSV2List(str);
+        } else if (num == -10) {
+            Sounds = llCSV2List(str);
+        } else if (num == -20) {
+            list args = llCSV2List(str);
+            redo            = llList2Integer(args,0);
+            chat            = llList2Integer(args,1);
+            ballusers       = llList2Integer(args,2);
+            menuusers       = llList2Integer(args,3);
+            SaneMenuOrder   = llList2Integer(args,4);
+            ReloadOnRez     = llList2Integer(args,5);
+
+            state on;
+        }
+    }
+
+    state_exit() {
+        llOwnerSay("("+llGetScriptName()+": "+(string)llGetFreeMemory()+" bytes free)");
+        llWhisper(0, Version + ": READY");
+    }
+}
+
+state re_on {
+    state_entry() {
+        state on;
+    }
+}
+
+state on {
+    state_entry() {
+        ch = channel();
+        owner = llGetOwner();
+        llListen(ch - 1, "", NULL_KEY, "");                      //listen for pressed buttons
+        // llWhisper(0, "Channel: " + (string)ch);
+    }
+    
+    on_rez(integer arg) {
+        if (ReloadOnRez) {
+            llResetScript();
+        }
+        BallCount = 0;
+        llSetTimerEvent(0.0);
+        state re_on;
+    }
+
+    touch_start(integer tcount) {
+        user0 = llDetectedKey(0);
+        touched(llDetectedGroup(0));
+    }
+    
+    listen(integer channel, string name, key id, string button) {
+        if (id != user) {
+            if (button == "Yes") {
+                user = id;
+                group = llSameGroup(user0);
+                mainMenu();
+            } else if (button != "Cancel") {
+                continMenu("Selection cancelled because ");
+            }
+            return;
+        }
+        if (handle_cmd(button, FALSE) && redo) doMenu(FALSE);
+    }
+
+
+    link_message(integer from, integer num, string str, key id) { 
+        if (str == "PRIMTOUCH") {
+            user0 = id;
+            touched(num);
+            return;
+        }
+        if (num == 0 && str == "AGAIN") {
+            llMessageLinked(LINK_THIS,0,"POSE", Posemsg);           //msg to pose
+            llMessageLinked(LINK_THIS,0,"POSEB", (key)pose);        //msg to memory
+            return;
+        }
+        if (num == -12002) {
+            handle_cmd(str, TRUE);
+            return;
+        }
+    }
+
+    timer() {
+        setBalls("LIVE");           //msg to balls: stay alive
+    }
+}    
diff --git a/LuaSL/Test sim/objects/onefang's test bed/~menucfg b/LuaSL/Test sim/objects/onefang's test bed/~menucfg
new file mode 100644
index 0000000..d38843d
--- /dev/null
+++ b/LuaSL/Test sim/objects/onefang's test bed/~menucfg
@@ -0,0 +1,296 @@
+// MLPV2 Version 2.2, by Learjeff Innis, based on
+// MLP MULTI-LOVE-POSE V1.2 - Copyright (c) 2006, by Miffy Fluffy (BSD License)
+// 15-color balls by Lizz Silverstar
+// autoback, multi-contin menu fixed
+// OpenSim port by Jez Ember
+// Meta 7 fixes by onefang Rejected
+
+integer MAX_BALLS   = 6;
+
+// Multicolor ball patch by Lizz Silverstar
+// The colors var used to store the color values is a 32 bit integer (0x00000000)
+// This is broken up into 8 nibbles of which we will currently use the lower 4 nibbles
+// the first ball color is in the lower 4 bits, the second in the next 4 bits, etc
+// Masks and shifting are used to store and extract the data.
+// 4 bits gives us 15 colors. 0 = no ball, 1-15 = color
+// these index values are then used by the ~ball code to set the correct color
+// 1st ball mask is 0x0000000F,  no shift
+// 2nd ball mask is 0x000000F0,  shift of 4
+// 3rd ball mask is 0x00000F00,  shift of 8
+// 4th ball mask is 0x0000F000,  shift of 12
+
+list Colornames = [
+    "HIDE", "PINK", "BLUE", "PINK2",
+    "BLUE2", "GREEN", "MAGENTA", "RED",
+    "ORANGE", "WHITE", "BLACK", "YELLOW",
+    "CYAN", "RED2", "TEAL", "GREEN2"];
+
+
+integer PoseIx;
+
+integer CurButtonIx;        // index of current button
+integer b0;                 // index of current button from start of current menu
+
+integer AutoBack;
+integer chat = TRUE;
+integer redo = TRUE;
+integer menuusers;
+integer group;
+integer ballusers;
+integer SaneMenuOrder;
+integer ReloadOnRez = FALSE;
+
+string cmd;
+string pose;
+string pose0;
+
+list buttons;
+list buttonindex;
+list commands;
+list menus;
+list balls;
+list users;
+
+list SoundNames;
+list Sounds;
+list LMButtons;
+list LMParms;
+
+
+// Globals for reading card config
+integer ConfigLineIndex;
+list    ConfigCards;        // list of names of config cards
+string  ConfigCardName;     // name of card being read
+integer ConfigCardIndex;    // index of next card to read
+key     ConfigQueryId;
+
+// Replacement for llListFindList which is currently broken in OSLSL
+integer myListFind(list a, string b) {
+    integer x;
+    integer l=llGetListLength(a);
+
+    for(x=0; x<l; x++) {
+        if(llList2String(a,x) == b) {
+            return x;
+        }
+    }
+    
+    return -1;
+}
+
+integer next_card()
+{
+    if (ConfigCardIndex >= llGetListLength(ConfigCards)) {
+        ConfigCards = [];
+        return (FALSE);
+    }
+    
+    ConfigLineIndex = 0;
+    ConfigCardName = llList2String(ConfigCards, ConfigCardIndex);
+    ConfigCardIndex++;
+    ConfigQueryId = llGetNotecardLine(ConfigCardName, ConfigLineIndex);
+    llOwnerSay("Reading " + ConfigCardName);
+    return (TRUE);
+}
+
+default {
+    state_entry() {
+        // ch = (integer)("0x"+llGetSubString((string)llGetKey(),-4,-1));  //fixed channel for prim
+        llMessageLinked(LINK_THIS,1,"OK?",(key)"");                    //msg to memory: ask if ready
+    }
+    link_message(integer from, integer num, string str, key id) {
+        if (num == 2 && str == "OK") state load;                                //memory ready
+    }
+}
+
+
+state load {
+    state_entry() {
+        string item;
+        ConfigCards = [];
+        integer n = llGetInventoryNumber(INVENTORY_NOTECARD);
+        while (n-- > 0) {
+            item = llGetInventoryName(INVENTORY_NOTECARD, n);
+            if (llSubStringIndex(item, ".MENUITEMS") != -1) {
+                ConfigCards += (list) item;
+            }
+        }
+
+        ConfigCardIndex = 0;
+        ConfigCards = llListSort(ConfigCards, 1, TRUE);
+        next_card();
+    }
+
+    dataserver(key query_id, string data) {
+        if (query_id != ConfigQueryId) {
+            return;
+        }                             
+        if (data == EOF) {
+            if (next_card()) {
+                return;
+            }
+            state on;
+        }
+
+        integer ix = llSubStringIndex(data,"//");                       //remove comments
+        if (ix != -1) {
+            if (ix == 0) data = "";
+            else data = llGetSubString(data, 0, ix - 1);
+        }
+
+        data = llStringTrim(data, STRING_TRIM_TAIL);
+        if (data != "") {
+            ix = llSubStringIndex(data," ");
+            cmd = data;                      
+            if (ix != -1) {                                             //split command from data
+                cmd = llGetSubString(data, 0, ix - 1);
+                data = llGetSubString(data, ix+1, -1);
+            }
+            list ldata = llParseStringKeepNulls(data,["  |  ","  | "," |  "," | "," |","| ","|"],[]);
+            string arg1 = llList2String(ldata, 0);
+            // llSay(0, cmd + ":" + data);
+            if (cmd == "MENU") {
+                integer auth;
+
+                if (PoseIx < 2) {
+                    llOwnerSay("warning: first two items in .MENUITEMS must be: POSE stand / POSE default");
+                }
+                llOwnerSay("loading '"+arg1+"' menu");
+
+                if (llList2String(ldata, 1) == "GROUP") auth = 1;       //access to submenus
+                else if (llList2String(ldata, 1) != "OWNER") auth = 2;  //0=owner 1=group 2=all
+
+                integer colors;
+                string ball_color;
+                integer colorIx;
+                integer ixB;
+                for (ixB=0; ixB < MAX_BALLS; ++ixB) { // for each possible ball
+                    ball_color = llList2String(ldata, ixB + 2); // get next color name from config
+
+                    colorIx = myListFind(Colornames, ball_color);
+
+                    if (colorIx != -1) {
+                        colors += (colorIx << (4 * ixB));    // 4 = bits per color (16 colors)
+                    }
+                }
+
+                menus += (list) arg1;
+                balls += (list) colors;
+                buttonindex += (list) CurButtonIx;
+                users += (list) auth;
+                
+//                if (llListFindList(buttons, (list)arg1) == -1) {
+
+                if (myListFind(buttons, arg1) == -1) {
+
+                    integer jx = myListFind(buttons, "-");                    
+
+                    if (jx != -1) {
+                        buttons = llListReplaceList(buttons, (list)arg1, jx, jx);
+                        // "TOMENU" is already in commands list from the 'TOMENU -'
+                    } else if (CurButtonIx > 2) {
+                        llOwnerSay("No unused 'TOMENU -' for " + arg1);
+                    }
+                }
+
+                b0 = 0;
+            } else if (cmd == "AUTOBACK") {
+                AutoBack = (arg1 != "0");
+            } else if (cmd == "NORELOAD") {
+                ReloadOnRez = (arg1 != "0");        // whether to reload menu on rez
+            } else if (cmd == "MENUORDER") {
+                SaneMenuOrder = (arg1 != "0");       // keep menu buttons in same order as in file
+            } else {
+                
+                // automatic menu extension (don't do for main menu)
+                if (b0 == 12 && llGetListLength(menus) > 1) {
+                    // Add a "more" button before last item
+                    integer ixA = -1;
+                    if (AutoBack) {
+                        ixA = -2;
+                         // Add a "BACK" button
+                        buttons  = llListInsertList(buttons, (list)"BACK", ixA);
+                        commands = llListInsertList(commands, (list)"BACK", ixA);
+                        ++CurButtonIx;
+                    }
+                    buttons  = llListInsertList(buttons, (list)"More-->", ixA);
+                    commands = llListInsertList(commands, (list)"MORE", ixA);
+                    ++CurButtonIx;
+                    b0 = -ixA;
+                }
+                if (cmd == "POSE") {
+                    llMessageLinked(LINK_THIS,9+PoseIx,data, (key)"");
+                    if (!PoseIx) pose0 = arg1;
+                    cmd = (string)PoseIx;
+                    ++PoseIx;
+                } else if (cmd == "REDO") {
+                    if (llList2String(ldata, 1) != "OFF") redo = 1;
+                } else if (cmd == "CHAT") {
+                    if (llList2String(ldata, 1) != "OFF") chat = 1;
+                } else if (cmd == "BALLUSERS") {
+                    if (llList2String(ldata, 1) == "GROUP") ballusers = 1;
+                } else if (cmd == "MENUUSERS") {
+                    if (llList2String(ldata, 1) == "GROUP") menuusers = 1;
+                    else if (llList2String(ldata, 1) != "OWNER") menuusers = 2;
+                } else if (cmd == "LINKMSG") {
+                    LMButtons += arg1;
+                    LMParms += llList2String(ldata, 1);
+                } else if (cmd == "SOUND") {
+                    SoundNames += (list) arg1;
+                    Sounds += (list) llList2String(ldata, 1);
+                }
+                commands += (list) cmd;
+                buttons += (list) arg1;
+                ++CurButtonIx;
+                ++b0;
+            }
+        }
+        ++ConfigLineIndex;
+        ConfigQueryId = llGetNotecardLine(ConfigCardName, ConfigLineIndex);         //read next line of menuitems notecard
+    }
+    state_exit() {
+        buttonindex += (list) CurButtonIx;    //enter last buttonindex
+        commands += (list) "";            //empty command for undefined buttons (-1)
+
+        integer ix;
+        integer count;
+        while ((ix = myListFind(buttons, "-")) != -1) {
+            ++count;
+            buttons = llDeleteSubList(buttons, ix, ix);
+            commands = llDeleteSubList(commands, ix, ix);
+        }
+        if (count) {
+            for (ix = 1; ix < llGetListLength(buttonindex); ++ix) {
+                buttonindex = llListReplaceList(buttonindex,
+                    (list)(llList2Integer(buttonindex, ix) - count), ix, ix);
+            }
+        }
+        // llMessageLinked(LINK_THIS,1,"LOADED",(string)PoseIx);                //msg to memory
+        llMessageLinked(LINK_THIS,9+PoseIx,"LOADED",(key)"");               //msg to pose
+    }
+}
+
+state on {
+    state_entry() {
+        llMessageLinked(LINK_THIS, -3, llList2CSV(menus),       (key)""); menus = [];
+        llMessageLinked(LINK_THIS, -4, llList2CSV(buttonindex), (key)""); buttonindex = [];
+        llMessageLinked(LINK_THIS, -5, llList2CSV(balls),       (key)""); balls = [];
+        llMessageLinked(LINK_THIS, -6, llList2CSV(users),       (key)""); users = [];
+        llMessageLinked(LINK_THIS, -7, llList2CSV(LMButtons),   (key)""); LMButtons = [];
+        
+        llMessageLinked(LINK_THIS, -8, llDumpList2String(LMParms, "|"), (key)""); LMParms = [];
+        
+        llMessageLinked(LINK_THIS, -9,  llList2CSV(SoundNames), (key)""); SoundNames = [];
+        llMessageLinked(LINK_THIS, -10, llList2CSV(Sounds),     (key)""); Sounds = [];
+
+        llMessageLinked(LINK_THIS, -2, llList2CSV(commands),    (key)""); commands = [];
+        llMessageLinked(LINK_THIS, -1, llList2CSV(buttons),     (key)""); buttons = [];
+
+                        
+        // finally, scalars (signals 'done' as well)
+        llMessageLinked(LINK_THIS, -20,
+            llList2CSV([ redo, chat, ballusers, menuusers, SaneMenuOrder, ReloadOnRez ]), (key)"");
+
+        llOwnerSay((string)CurButtonIx+" menuitems loaded ("+llGetScriptName()+": "+(string)llGetFreeMemory()+" bytes free)");
+    }
+}